Уникальность смартфона (планшета)

[Steepe_Hare]

Есть ли у смартфона (планшета), работающего под управлением Android, уникальный ID и как его получить средствами Delphi?

Спасибо.

[Равиль Зарипов (ZuBy)]

//uses
//  AndroidApi.Helpers, AndroidApi.JNI.JavaTypes, AndroidApi.JNI.Provider;
var
  deviceID: JString;
begin
  deviceID := TJSettings_Secure.JavaClass.getString(TAndroidHelper.Context.getContentResolver,
    TJSettings_Secure.JavaClass.ANDROID_ID);
  ShowMessage(JStringToString(deviceID));
end;

 

[krapotkin]

по слухам, у дешевых китайцев он один на всех

[Равиль Зарипов (ZuBy)]

20 минут назад, krapotkin сказал:

по слухам, у дешевых китайцев он один на всех

тогда можно комбинировать с еще какими нибудь данными девайса и в md5 зашивать

[Равиль Зарипов (ZuBy)]

например вот так

function getDeviceId: string;
// uses
// Androidapi.Jni.GraphicsContentViewText, Androidapi.JNIBridge,
// Androidapi.Helpers, Androidapi.Jni.JavaTypes,
// Androidapi.Jni.Provider, Androidapi.Jni.Telephony,
// System.Hash;
var
  androidID: string;
  deviceID: string;
  TelephoneServiceNative: JObject;
  TelMan: JTelephonyManager;
begin
  androidID := JStringToString(TJSettings_Secure.JavaClass.getString(TAndroidHelper.Context.getContentResolver,
    TJSettings_Secure.JavaClass.ANDROID_ID));

  TelephoneServiceNative := TAndroidHelper.Context.getSystemService(TJContext.JavaClass.TELEPHONY_SERVICE);
  if TelephoneServiceNative <> nil then
  begin
    TelMan := TJTelephonyManager.Wrap((TelephoneServiceNative as ILocalObject).GetObjectID);
    deviceID := JStringToString(TelMan.getDeviceId);
  end
  else
    deviceID := '';

  Result := THashMD5.GetHashString(androidID + deviceID);
end;

UPDATE: не забываем про разрешение READ_PHONE_STATE